/* Plot.aml
/*
/* Plotting aml for Generalized Thermal Maturity Map of Alaska (Map I-2494)
/*
/* Revised for Digital Data Series release: 13 February 1998
/* 
/* This aml converts a series of coverages into a single graphics (.gra) file, 
/* then it converts the graphics file into an Encapsulated Postscript (.eps) file
/* that can be sent to a plotter for hard copy output
/*
/* Usage:
/* (1) cd into the "map/miscfiles" directory
/* (2) Start ARC/INFO
/* (3) At the ARC prompt, type the following to run plotting aml: &run plot.aml
/* (4) when prompted "enter name of graphics file", type in a file name
/*     and hit "enter" (ARC will add the suffixes .gra and .eps to your file name)
/*
/*****************************************************************************
/*
&severity &warning &ignore; &severity &error &fail
arcplot
&if [show program] ne ARCPLOT &then
  &return &warning WARNING! PROGRAM RUNS IN ARCPLOT ONLY!
/*
/* Create an Arc/Info graphics file: %name$plot%.gra
/*
&sv name$plot [response 'Enter name of graphics file']
display 1040 
%name$plot% 

&type 
&type Display complete.

/*
/* Page setup
/* Note: The full-scale map is 56 inches wide and 34 inches high. To
/* rotate the map (as may be required for plotting on a roll plotter)
/* see the postscript command lines near the end of the end of this file
/* 
pagesize 56 34
pageunits inches
mapex ../coverages/main
mapunits meters
mapscale 2500000
mappos -2000000 7450000 28 16.4  /* to shift map 1" right, and -0.6
maplimits 1 1 55 33              /* neatline box  1 1 55 33      

&type Page setup complete.

/*
/* Set symbolsets
/*
lineset aktherm.lin
markerset aktherm.mrk
shadeset aktherm.shd 
textset aktherm.txt
&type Symbolsets complete.

weeddraw off

/*
/* Color polygons
/*
polygonshades ../coverages/main ptype ../coverages/akthermpoly.lut
&type Polygonshades complete.
/*
/* Plot the base map
/*
linesymbol 7
linecolor CMYK,100,0,0,0
arcs ../coverages/base
/*
/* Draw point symbols
/*
/* VR outcrop samples
markersymbol 118     /* empty square
markersize 0.05
reselect ../coverages/outcrops points CAI = 0.0
reselect ../coverages/outcrops points CMDS cn ' '
points ../coverages/outcrops
/*
/* CAI outcrop samples
clearselect
markersymbol 121     /* empty triangle
markersize 0.05
reselect ../coverages/outcrops points VR = 0.0
reselect ../coverages/outcrops points CMDS cn ' '
points ../coverages/outcrops
/*
/* Color offshore VR outcrop symbols
/* 
clearselect
markersymbol 117     /* yellow square
reselect ../coverages/outcrops points CMDS = 'U'
points ../coverages/outcrops

clearselect
markersymbol 116     /* orange square
reselect ../coverages/outcrops points CMDS = 'M1'
points ../coverages/outcrops

clearselect
markersymbol 115     /* red square
reselect ../coverages/outcrops points CMDS = 'O'
points ../coverages/outcrops

clearselect
markersymbol 114     /* purple square
reselect ../coverages/outcrops points CMDS = 'S'
points ../coverages/outcrops

clearselect
/* 
/* Plot towns
/* 
markersymbol 122     /* black circle
points ../coverages/towns
/* 
/* Plot wells
/* 
/* First plot wells with callouts
markersymbol 124     /* black circle with 4 arms
markersize 0.1
points ../coverages/wells2
/* Next plot wells used to constrain contours
markersymbol 125     /* empty circle with 4 arms
markersize 0.1
points ../coverages/wells1
/* 
/*Plot contours (elevation of U/M1 boundary)
/* 
linesymbol 7
linecolor CMYK,0,100,0,0
unselect ../coverages/contours arcs ltype = 'scratch boundary, certain'
arcs ../coverages/contours                                   
/* 
/* Plot the graticule:
/* 
linesymbol 7
linecolor CMYK,0,0,0,50
arcs ../coverages/graticule

clearselect

/* 
/* Draw geology (lines)
/* 
/* First unselect lines that should not be plotted:
unselect ../coverages/main arcs ltype = 'water boundary, certain'
unselect ../coverages/main arcs ltype = 'glacier boundary, certain'
unselect ../coverages/main arcs ltype = 'scratch boundary, certain'
unselect ../coverages/main arcs ltype = 'map boundary, scan'
/* Draw all other lines with appropriate symbols, using INFO look-up tables
arclines ../coverages/main ltype ../coverages/akthermline.lut
/* 
/* Draw Annotation
/* 
annotext ../coverages/text 
/* Draw text leaders
linesymbol 7
arcs ../coverages/text

&type Lines, markers, points, annotation, and graticule complete.

/* 
/* Route for Canada/AK border
/* 
lineset plotter; linedelete all; lineset carto.lin
routelines ../coverages/akcanborder akborder 143

&type International border complete.

/* 
/* Place EPS file with insets, etc.
/* 
eps ../insetfigures/insets.eps -0.91 -1.07  

&type Inset figures complete.

/* 
/* Quit ARCPLOT
/* 
quit

&type Graphics metafile (.gra) created, now converting to postscript.

/* 
/* Create postscript file for electrostatic or inkjet plotter:
/* 
/* Two versions of the postscript command are given below. Both make
/* use of a postscript parameter file (in directory miscfiles) to
/* set output resolution to 2400 dpi. This will make all linework draw
/* at the correct lineweight and all annotation draw smoothly. The
/* resulting 2400 dpi-resolution plotfile can be plotted on any lower
/* resolution plotting device (as low as 300dpi)

/* In addition, the parameter file on the _second_ postscript line below
/* will rotate the plot 90 degrees (portrait orientation), as is required on
/* many roll plotters. This is the default setting. If you do not want your
/* plot rotated, you must ³comment out² the _second_ postscript command line
/* by, adding /* at the front of the line. Then, activate the _first_
/* postscript command line by removing the /* at the beginning of the line.


/* postscript %name$plot%.gra %name$plot%.eps 1 res2400.prm
postscript %name$plot%.gra %name$plot%.eps 1 rot90.prm


&type Postscript file completed. Ending plot.aml.

&return